# CreateDateTime

Returns a valid date/time object.

See also CreateDate, CreateTime, CreateODBCDateTime, and Now.

### Syntax

    CreateDateTime(year, month, day, hour, minute, second)

##### year

Number representing the year in the range 100-9999.

##### month

Number representing the month of the year, ranging from 1 (January) to 12 (December).

##### day

Number representing the day of the month, ranging from 1 to 31.

##### hour

Number representing the hour, ranging from 0 to 23.

##### minute

Number representing the minute, ranging from 0 to 59.

##### second

Number representing the second, ranging from 0 to 59.

### Usage

Years from 0 to 29 are interpreted as 21st century values. Years 30 to 99 are interpreted as 20th century values.

### Examples

    <!--- This example shows how to use CreateDateTime --->
    <HTML>
    <HEAD>
    <TITLE>
    CreateDateTime Example
    </TITLE>
    </HEAD>

    <BODY BGCOLOR=silver>
    <H3>CreateDateTime Example</H3>

    <CFIF IsDefined("form.year")>
    Your date value, presented using different CF date functions:
    <CFSET yourDate = CreateDateTime(form.year, form.month, form.day,
        form.hour, form.minute, form.second)>
    <CFOUTPUT>
    <UL>
        <LI>Built with CreateDate:
          #CreateDate(form.year, form.month,form.day)#
        <LI>Built with CreateDateTime:
           #CreateDateTime(form.year, form.month, form.day, form.hour,
               form.minute,form.second)#
        <LI>Built with CreateODBCDate: #CreateODBCDate(yourDate)#
        <LI>Built with CreateODBCDateTime: #CreateODBCDateTime(yourDate)#
    </UL>

    <P>The same value can be formatted with dateFormat:
    <UL>
        <LI>Built with CreateDate:
           #DateFormat(CreateDate
             (form.year,form.month,form.day), "mmm-dd-yyyy")#
        <LI>Built with CreateDateTime:
            #DateFormat(CreateDateTime
              (form.year, form.month, form.day, form.hour,
                form.minute, form.second))#
        <LI>Built with CreateODBCDate:
           #DateFormat(CreateODBCDate(yourDate), "mmmm d, yyyy")#
        <LI>Built with CreateODBCDateTime:
           #DateFormat(CreateODBCDateTime(yourDate), "d/m/yy")#
    </UL>
    </CFOUTPUT>
    </CFIF>

    <CFFORM ACTION="createdatetime.cfm" METHOD="POST">
    <P>Please enter the year, month and day in integer format for
    the date value you would like to view:
    <PRE>
    Year    <CFINPUT TYPE="Text" NAME="year" VALUE="1998" VALIDATE="integer"
      REQUIRED="Yes">
    Month    <CFINPUT TYPE="Text" NAME="month" VALUE="6" RANGE="1,12"
      MESSAGE="Please enter a month (1-12)" VALIDATE="integer"
        REQUIRED="Yes">
    Day    <CFINPUT TYPE="Text" NAME="day" VALUE="8" RANGE="1,31"
      MESSAGE="Please enter a day of the month (1-31)" VALIDATE="integer"
        REQUIRED="Yes">
    Hour    <CFINPUT TYPE="Text" NAME="hour" VALUE="16" RANGE="0,23"
      MESSAGE="You must enter an hour (0-23)" VALIDATE="integer"
        REQUIRED="Yes">
    Minute    <CFINPUT TYPE="Text" NAME="minute" VALUE="12" RANGE="0,59"
      MESSAGE="You must enter a minute value (0-59)" VALIDATE="integer"
        REQUIRED="Yes">
    Second    <CFINPUT TYPE="Text" NAME="second" VALUE="0" RANGE="0,59"
      MESSAGE="You must enter a value for seconds (0-59)" VALIDATE="integer"
        REQUIRED="Yes">
    </PRE>
    <P><INPUT TYPE="Submit" NAME=""> <INPUT TYPE="RESET">
    </CFFORM>
    </BODY>
    </HTML>