<!--- This example shows the use of REFind --->

<HTML>

<HEAD>
<TITLE>
REFind Example
</TITLE>
</HEAD>

<BASEFONT FACE="Arial, Helvetica" SIZE=2>
<BODY  bgcolor="#FFFFD5">

<H3>REFind Example</H3>

<P>This example demonstrates the use of the REFind function with and without the <i>returnsubexpressions</i> parameter set to True.</P> 

If you do not use the <i>returnsubexpressions</i> parameter, REFind returns the position of the first occurrence of a regular expression in a string starting from the specified position.  Returns 0 if no occurrences are found.
</P>

<P>REFind("a+c+", "abcaaccdd"):	
<CFOUTPUT>#REFind("a+c+", "abcaaccdd")#</CFOUTPUT></P>
<P>REFind("a+c*", "abcaaccdd"):	
<CFOUTPUT>#REFind("a+c*", "abcaaccdd")#</CFOUTPUT></P>
<P>REFind("[[:upper:]]", "abcaacCDD"):	
<CFOUTPUT>#REFind("[[:upper:]]", "abcaacCDD")#</CFOUTPUT></P>
<P>REFind("[\?&]rep=", "report.cfm?rep=1234&u=5"):	<CFOUTPUT>#REFind("[\?&]rep=", "report.cfm?rep=1234&u=5")#</CFOUTPUT>
</P>
<!--- Use REFind with 1 as startPos and returnMatchedSubexpressions = 
	TRUE --->
<HR size="2" color="#0000A0">

<P>If you do use the <i>returnssubexpression</i> parameter, REFind 
returns the position and length of the first occurrence of a regular expression in a string 
starting from the specified position. The position and length variables are stored in a structure. 
In order to access the position and length information, you must use the keys 
<i>pos</i> and <i>len</i>, respectively.</P>

<CFSET teststring ="The cat in the hat hat came back!">
<P>The string in which the function is to search is: <CFOUTPUT><b>#teststring#</b></CFOUTPUT>.</P>
<P>The first call to REFind to search this string is: 
<b>REFind("[[:alpha:]]+",testString,1,"TRUE")</b></P>
<P>This function returns a structure that contains two arrays: pos and len.</P>
<P>In order to create this structure you can use a CFSET statement, for example:</P>
&lt;CFSET st = REFind("[[:alpha:]]+",testString,1,"TRUE")&gt;
<CFSET st = REFind("[[:alpha:]]+",testString,1,"TRUE")>
<P>
	<CFOUTPUT>
	The number of elements in each array: #ArrayLen(st.pos)#.
	</CFOUTPUT>
</P>
<P><b>The number of elements in the pos and len arrays will always be one if you 
do not use parentheses to denote subexpressions in the regular expression.</b></P>
<P>The value of st.pos[1] is: <CFOUTPUT>#st.pos[1]#.</CFOUTPUT></P>
<P>The value of st.len[1] is: <CFOUTPUT>#st.len[1]#.</CFOUTPUT></P>
<P>
	<CFOUTPUT>
	Substring is <b>[#Mid(testString,st.pos[1],st.len[1])#]</B>
	</CFOUTPUT>
</P>

<HR size="2" color="#0000A0">

<P>However, if you use parentheses to denote subexpressions in the regular 
expression, you will find that the first element contains the position and length 
of the first instance of the whole expression. The position and length of the 
first instance of each subexpression within will be included in additional array 
elements.</P>

<P>For example: &lt;CFSET st1 = REFind("([[:alpha:]]+)[ ]+(\1)",testString,1,"TRUE")&gt;</P>

<CFSET st1 = REFind("([[:alpha:]]+)[ ]+(\1)",testString,1,"TRUE")>

<P>The number of elements in each array is <CFOUTPUT>#ArrayLen(st1.pos)#</CFOUTPUT>.</P>

<P>First whole expression match; position is 
<CFOUTPUT>
#st1.pos[1]#; length is #st1.len[1]#; 
whole expression match is <B>[#Mid(testString,st1.pos[1],st1.len[1])#]</B>
</CFOUTPUT></P>

<P>Subsequent elements of the arrays provide the position and length of the first instance of each parenthesized subexpression therein.</P>
 <CFLOOP index="i" from="2" to="#ArrayLen(st1.pos)#">
	<p><CFOUTPUT>Position is #st1.pos[i]#; Length is #st1.len[i]#; Substring is <B>[#Mid(testString,st1.pos[i],st1.len[i])#]</B></CFOUTPUT></p>
</CFLOOP><BR>   

</BODY>

</HTML>       