# CreateDate

Returns a valid date/time object.

See also CreateDateTime and CreateODBCDate.

### Syntax

    CreateDate(year, month, day)

##### year

Number representing the year in the range 100-9999. Years from 0 to 29 are interpreted as 21st century values. Years 30 to 99 are interpreted as 20th century values.

##### month

Number representing the month of the year, ranging from 1 (January) to 12 (December).

##### day

Number representing the day of the month, ranging from 1 to 31.

### Usage

CreateDate is a subset of CreateDateTime.

Time in the returned object is set to 00:00:00.

### Examples

    <!---------------------------------------------------------
    This example shows how to use CreateDate, CreateDateTime, and
    createODBCdate
    ----------------------------------------------------------->

    <HTML>

    <HEAD>
    <TITLE>
    CreateDate Example
    </TITLE>
    </HEAD>

    <basefont face="Arial, Helvetica" size=2>
    <body  bgcolor="#FFFFD5">

    <H3>CreateDate Example</H3>

    <CFIF IsDefined("FORM.year")>
    Your date value, presented using different CF date functions:
    <CFSET yourDate = CreateDate(FORM.year, FORM.month, FORM.day)>

    <CFOUTPUT>
    <UL>
        <LI>Built with CreateDate: #CreateDate(FORM.year, FORM.month,
                FORM.day)#
        <LI>Built with CreateDateTime: #CreateDateTime(FORM.year, FORM.month,
                FORM.day, 12,13,0)#
        <LI>Built with CreateODBCDate: #CreateODBCDate(yourDate)#
        <LI>Built with CreateODBCDateTime: #CreateODBCDateTime(yourDate)#
    </UL>

    <P>The same value can be formatted with dateFormat:
    <UL>
        <LI>Built with CreateDate: #DateFormat(CreateDate(FORM.year,
                FORM.month, FORM.day), "mmm-dd-yyyy")#
        <LI>Built with CreateDateTime: #DateFormat(CreateDateTime(FORM.year,
                FORM.month, FORM.day, 12,13,0))#
        <LI>Built with CreateODBCDate: #DateFormat(CreateODBCDate(yourDate),
                "mmmm d, yyyy")#
        <LI>Built with CreateODBCDateTime:
                #DateFormat(CreateODBCDateTime(yourDate), "d/m/yy")#
    </UL>

    </CFOUTPUT>

    </CFIF>

    <CFFORM ACTION="createdate.cfm" METHOD="POST">
    <P>Please enter the year, month and day in integer format for
    the date value you would like to view:
    <PRE>
    Year    <CFINPUT TYPE="Text" NAME="year" VALUE="1998" VALIDATE="integer"
      REQUIRED="Yes">
    Month    <CFINPUT TYPE="Text" NAME="month" VALUE="6" VALIDATE="integer"
      REQUIRED="Yes">
    Day    <CFINPUT TYPE="Text" NAME="day" VALUE="8" VALIDATE="integer"
      REQUIRED="Yes">
    </PRE>
    <P><INPUT TYPE="Submit" NAME=""> <INPUT TYPE="RESET">
    </CFFORM>

    </BODY>
    </HTML>