# TimeFormat

Returns a custom-formatted time value. If no mask is specified, the TimeFormat function returns time value using the hh:mm tt format.

See also CreateTime, Now, and ParseDateTime.

### Syntax

    TimeFormat(time [, mask ])

##### time

Any date/time value or string convertible to a time value.

##### mask

A set of masking characters determining the format:

- `h` -- Hours with no leading zero for single-digit hours. (Uses a 12-hour clock.)
- `hh` -- Hours with a leading zero for single-digit hours. (Uses a 12-hour clock.)
- `H` -- Hours with no leading zero for single-digit hours. (Uses a 24-hour clock.)
- `HH` -- Hours with a leading zero for single-digit hours. (Uses a 24-hour clock.)
- `m` -- Minutes with no leading zero for single-digit minutes
- `mm` -- Minutes with a leading zero for single-digit minutes
- `s` -- Seconds with no leading zero for single-digit seconds
- `ss` -- Seconds with a leading zero for single-digit seconds
- `t` -- Single-character time marker string, such as A or P
- `tt` -- Multiple-character time marker string, such as AM or PM

### Usage

When passing a date/time value as a string, make sure it is enclosed in quotes. Otherwise, it is interpreted as a number representation of a date/time object, returning undesired results.

### Examples

    <!--- This example shows the various types of output
    possible with TimeFormat --->
    <HTML>
    <HEAD>
    <TITLE>
    TimeFormat Example
    </TITLE>
    </HEAD>
    <CFSET todayDate = #Now()#>

    <BODY>
    <H3>TimeFormat Example</H3>

    <P>Today's date is <CFOUTPUT>#todayDate#</CFOUTPUT>.

    <P>Using Timeformat, we can display that date/time value
    in a number of different ways:
    <CFOUTPUT>
    <UL>
        <LI>#TimeFormat(todayDate)#
        <LI>#TimeFormat(todayDate, "hh:mm:ss")#
        <LI>#TimeFormat(todayDate, "hh:mm:sst")#
        <LI>#TimeFormat(todayDate, "hh:mm:sstt")#
        <LI>#TimeFormat(todayDate, "HH:mm:ss")#
    </UL>

    </CFOUTPUT>

    </BODY>
    </HTML>